Challenge auth

;  by wiebe @ QuakeNet
;  written and tested on mIRC 6.16
;
; What does this script do?
;
;  auths with Q using the 'CHALLENGEAUTH' command
;
; How to use this script?
;
;  load the script and connect to quakenet
;  (if already connected, /msg Q challenge)
;  default mode is 'semi-automatic'
;  for more info, read below
;

on $*:notice:/^CHALLENGE MD5 ([0-9a-f]){32}$/:?:{
  if ($fulladdress != Q!TheQBot@CServe.quakenet.org) || ($network != QuakeNet) || (*.quakenet.org !iswm $server) { !return }
  !echo -egst *** Attempting to CHALLENGE AUTH with Q from $server $chr(91) $+ $serverip $+ $chr(93)

  ; this is the most secure way, 'semi-automatic'
  ; sets the command ready for you, but you have to enter the account and password everytime
  ; for paranoid people, change the -ns to -s, 
  ; that way you see the command in status window and have to press enter yourself
  ; do not change the following 2 lines, unless you know what you are doing

  !editbox -ns //!.msg Q@CServe.quakenet.org CHALLENGEAUTH $$!?*="account" $!md5($left($$?*="password",10) $3 $+ )
  !return


  ; if you want automatic auth, despite the risks..,
  ; comment the above 2 lines, like this:
  ;  ;!editbox ..
  ;  ;!return
  ; and replace 'username' and 'password' below

  !var %j = $&
    username
  !var %s = $&
    password
  !.msg $+(Q,$chr(64),CSe,rve,$chr(46),qua,ken,et,.o,rg,$chr(32),CH,$chr(65),LL,$chr(69),NG,$chr(69),$chr(65),$chr(85),TH) %j $md5($left(%s,10) $3)
}

on *:notice:Either you haven't requested a challenge yet or your one expired.:?:{
  if ($fulladdress != Q!TheQBot@CServe.quakenet.org) || ($network != QuakeNet) || (*.quakenet.org !iswm $server) { !return }
  !.msg Q@CServe.quakenet.org CHALLENGE
}

on *:connect:{
  if ($network != QuakeNet) || (*.quakenet.org !iswm $server) { !return }
  !.msg Q@CServe.quakenet.org CHALLENGE
}